_________________________________________________________________________

           Title: Snailrace
         Version: 1.1
          Author: Henrik Stenberg <henrik.s@interact.se>
            Size: 796 bytes
     Description: Compete against the computer and bet your money on snails.
                  Goal of the game:  Get $50000
                  Note:   How much money you win depend on how many winners 
                  there are and how much money there is in the pot.
                  
_________________________________________________________________________

Command translation:

        -->     Assign (Above DEL)
        ==>     Then (Shift  7  F1  F1)
        <=      Less or equal (Shift  7  F2  F6)
        >=      Greater or equal (Shift  7  F2  F5)
        @       Disp (Shift  7  F5)
        ±       Theta (Alpha  Range)
        r       (Alpha  Graph)

_________________________________________________________________________

 Program :

'SNAILRACE
Mcl
92 --> W                                        ;9700GE: 125 --> W
50000 --> Z                                     ;Change this if you want a higher goal
2000 --> E~H
Lbl 0
E>0 ==> "CASIO GOT:":E @
F>0 ==> "TI GOT:":F @
G>0 ==> "HP GOT:":G @
H>0 ==> "YOU GOT:":H @
E>0 ==> "CASIO BET:":Int (Ran#E --> I @
F>0 ==> "TI BET:":Int (Ran#F --> J @
G>0 ==> "HP BET:":Int (Ran#G --> K @
"YOU BET"? --> L
L>H ==> H --> L
"SNAIL 1,2,3,4" @
E>0 ==> "CASIO CHOOSE:":Int (3Ran#+1 --> M @
F>0 ==> "TI CHOOSE:":Int (3Ran#+1 --> N @
G>0 ==> "HP CHOOSE:":Int (3Ran#+1 --> O @
"YOU CHOOSE"? --> P
1 --> A~D
0 --> S~V
Range 1,95,0,1,63,0                             ;9700GE: Range 1,127,0,1,63,0
Plot W,1
Plot W,63
Line
Lbl 1
Plot A,52
Plot B,39
Plot C,26
Plot D,13
A+3Ran# --> A
B+3Ran# --> B
C+3Ran# --> C
D+3Ran# --> D
A<W ==> B<W ==> C<W ==> D<W ==> Goto 1
A>=W ==> 1 --> R
B>=W ==> 2 --> R
C>=W ==> 3 --> R
D>=W ==> 4 --> R
"WINNER SNAIL:":R @
M=R ==> 1 --> S
N=R ==> 1 --> T
O=R ==> 1 --> U
P=R ==> 1 --> V
0 --> Y
I+J+K+L+±+1000 --> X
S=1 ==> I+Y --> Y
T=1 ==> J+Y --> Y
U=1 ==> K+Y --> Y
V=1 ==> L+Y --> Y
S=1 ==> Int(I/Y*X+E --> E
T=1 ==> Int(J/Y*X+F --> F
U=1 ==> Int(K/Y*X+G --> G
V=1 ==> Int(L/Y*X+H --> H
S=0 ==> E-I --> E
T=0 ==> F-J --> F
U=0 ==> G-K --> G
V=0 ==> H-L --> H
S+T+U+V --> r
±>0 ==> r>0 ==> "BONUS REWARD!" @               ;Winners get a bonus if no one won previous race
r=0 ==> X --> ±
r>0 ==> 0 --> ±
H<=0 ==> Goto 3
E>=Z ==> Goto 3
F>=Z ==> Goto 3
G>=Z ==> Goto 3
H>=Z ==> Goto 2
Goto 0
Lbl 2
"    YOU WON!"
Goto 4
Lbl 3
"    GAMEOVER"
Lbl 4
"See ya soon!"

_________________________________________________________________________