_____________________________________________________________________________

        Title: Confusion
      Version: 2.55
       Since : 02/11/1997
  Last update: 06/27/1997
       Author: RATTANAM WONGKALASIN - B3703007@POPEYE.SUT.AC.TH
        Model: Designed on a 9750,9850,9850PLUS,9950,9950 PLUS
  Description: same game in windows 

-----------------------------------------------------------------------------

COMMAND TRANSLATION:

                _        "display"              (SHIFT, VAR, F5)
                <>       "not equal to"         (SHIFT, VAR, F6, F3, F2)
                <=       "less than or equal to"(SHIFT, VAR, F6, F3, F6)
                >=       "more than or equal to"(SHIFT, VAR, F6, F3, F5)
                ->       "put in to"
                =>       "then"                 (SHIFT, VAR, F3, F3)
              Ran#       gives a random number. (OPTN, F6, F3, F4)
                /        divide

-----------------------------------------------------------------------------

PROGRAM CODE:

"CONFUSiON"
V-window 1,127,0,1,63,0
Cls
Norm
Coordoff
0->A~Z
"Use KeY"
"1. PLot 2. ArroW :"?->Z
Z<>2=>1->Z
CoordOn
For 1->I To 7
F-Line 9I+9,12,9I+9,60
F-Line 18,8I+4,72,8I+4
Next
Identity 6->Mat A
Text 5,88,"LoAdiNg"
1->C
Fill(0,Mat A
For 1->I To 18
For 1->J To 2
Do
Intg (6Ran#+1->A
Intg (6Ran#+1->B
LpWhile Mat A[A,B]<>0
I->Mat A[A,B
C<15=>Isz C
C<=15=>F-Line C+86,53,C+86,50
Next
Isz C
F-Line C+86,53,C+86,50
Next
0->C~F
1->U
Z=2=>1->A
Z=2=>6->B
Text 25,96,"SCorE"
Text 11,85,"        "
Text 5,88,"  TiME "
23->K
56->L
Lbl 0
PlotOn 18,16
Z=2=>Goto P
Plot K,L_
0->A~B
X->K
Y->L
Y=60=>Goto Z
For 1->I To 6
X-9I-9>0 And X-9I-9<9=>I->A
Next
For 1->I To 6
Y-8I-4>0 And Y-8I-4<8=>I->B
Next
A=0 Or B=0=>Goto 0
0=Mat A[B,A=>Goto 0
C=1=>A=M=>B=N=>Goto 0
C=0=>(A=P And B=Q) Or (A=R And B=S)=>Goto 0
Lbl J
Text 12,100,U
C=0=>A->M
C=0=>B->N
C=0=>Mat A[B,A->D~F
C=1=>Mat A[B,A->E~F
54-8B->G
9A+12->H
F<=9=>Text G,H,F
F=10=>Text G,H,"A"
F=11=>Text G,H,"T"
F=12=>Text G,H,"C"
F=13=>Text G,H,"D"
F=14=>Text G,H,"R"
F=15=>Text G,H,"F"
F=16=>Text G,H,"Y"
F=17=>Text G,H,"H"
F=18=>Text G,H,"?"
If C=1
Then If D=E
Then 0->Mat A[B,A
0->Mat A[N,M
Isz V
0->O~S
Else 1->O
A->P
B->Q
M->R
N->S
IfEnd
IfEnd
If O=1 And C=0
Then Text 54-8Q,9P+12," "
Text 54-8S,9R+12," "
IfEnd
Isz U
Isz C
C=2=>0->C
Text 32,102,V
PlotOn 45,32
V=18=>Goto 1
Goto 0
Lbl 1
Text 50,88,"WinNER"
Plot 0,0_
Lbl Z
"End of Game"
Stop
Lbl P
U<>1=>27->T
U<>1=>Goto 6
Lbl 7
Text 54-8B,13+9A,"+"
Text 25,96,"S"
Do
Getkey->T
LpWhile T<>28 And T<>27 And T<>37 And T<>38 And T<>29 And T<>79
Text 54-8B,13+9A," "
Lbl 6
If T=27 Or T=28 Or T=37 Or T=38
Then Do
T=27=>A+1->A
T=27=>A>6=>B-1->B
T=37=>B-1->B
T=37=>B<1=>A+1->A
T=38=>A-1->A
T=38=>A<1=>B+1->B
T=28=>B+1->B
T=28=>B>6=>A-1->A
A>6=>1->A
B>6=>1->B
A<1=>6->A
B<1=>6->B
LpWhile (Mat A[B,A]=0) Or (C=1 And A=M And B=N) Or (C=0 And ((A=P And B=Q) Or (A=R And B=S)))
Goto 7
IfEnd
T=29=>Goto Z
Goto J

====================================
My Casio 9850 Game

1 IQMAX -My BEST CASIO CFX-9850 Game
2 XO-GOLD -Best of tic tac tae Game
3 PROCARD -3 in 1 game BLACKJACK, POGDENG, BLACKDENG
4 PUZZLE -Easy to write program but not easy to play
5 MINS SWEEPER -Same for win, Good game
6 CONFUSION -Same for win, Good game for test you memmory
7 HORSE RACING -Fun game
8 CALENDAR -9999 year Calendar viewer
9 NANNAN-T -2 in 1 game TOWERS OF HANOI and PAGED POWER
10 AND MORE...
=======================================
Thank for
Den Thana -idea for PROCARD
P'_Peak -original 9700 HORSE RACING and CROSS
THINK ,YO ,EAK ,UOD, BEE and more for test my games
AOD -for "make and test" Casio-to-Casio Cable and Casio-to-PC interface
NY R-COM -for idea and technical

(C) 1997 By Rattanam wongkalasin -NarM- Telecom Eng. SUT Thailand