_________________________________________________________________________

           Title: Pong Pro
         Version: v1.0
          Author: Hidetake Jo (hjo@engin.umich.edu)
            Size: 
	     Model: 9850+
     Description: 

Lots of improvements since the Older version of pong9850.  

New Features Include:

-Player sprites move more than 10 times faster than before
-Better Interface and overall Look and Feel
-Ball speed is faster
-Ball speed can be increased with the up arrow and decreased
 with the down arrow key.  There is a little Icon at the bottom 
 of the screen to show the current Ball Speed
-Time display.  Ticking time at bottom of screen to measure
 time played(somewhat accurate).

Controls: 

Player One:  "1"    move paddle up
             "0"    move paddle down

Player Two:  "-"    move paddle up
             "EXE"  move paddle down

General:     "Up arrow key"   Speed up Ball (max 5)
             "down arrow key" Speed down Ball (min 1)

_________________________________________________________________________

 Program :

Cls
ViewWindow 1,60,1,1,64,1
0->A~Z
1->Z
1->V
Plot 1,10
Plot 59,10
Line
Plot 1,54
Plot 59,54
Line
Text 5,40,"-PONG PRO-"
Text 57,9,"SPEED:"
Text 57,38,V
1->A~C
10->B
1->D
30->G~H
Text 57,58,"TIME:"
Text 30,5,"I"
Text 30,120,"I"
While Z=1
PlotOn A,B
PlotOff A,B
A+C->A
B+D->B
B>49 => -V ->D
B<14 => V->D
S+0.25->S
Frac S=0 => Text 57,85,"       "  {7 spaces}
Frac S=0 => Text 57,85,S
If GetKey=28
Then V+1->V
V>5 => V-1->V
C<0 =>-V->C
C>0 =>V->C
D>0 => V->D
D<0 => -V->D
Text 57,38," "    {1 space}
Text 57,38,V
IfEnd
IfGetKey=37
Then V-1->V
V<1 =>V+1->V
C<0 =>-V->C
C>0 =>V->C
D>0 => V->D
D<0 => -V->D
Text 57,38," "    {1 space}
Text 57,38,V
IfEnd
If GetKey=72
Then G-7->G
G<12 => G+7->G
Text G,5,"I"
Text G+7,5," "    {1 space}
IfEnd
If GetKey=71
Then G+7->G
G>47 => G-7->G
Text G,5,"I"
Text G-7,5," "     {1 space}
IfEnd
If GetKey=32
Then H-7->H
H<12 => H+7->H
Text H,120,"I"
Text H+7,120," "    {1 space}
IfEnd
If GetKey=31
Then H+7->H
H>50 => H-7->H
Text H,120,"I"
Text H-7,120," "     {1 space}
IfEnd
IF A <6
Then B >= 64-G => B =< 64-G+7 => V->C
IfEnd
If A >53
Then B >= 64-H => B =< 64-H+7 => -V->C
IfEnd
A >65 =>2->Z
A<-2 => 3->Z
WhileEnd
Z=2=>Text 30,45,"LEFT WINS"
Z=3=>Text 30,45,"RIGHT WINS"
_________________________________________________________________________